Батник таймер для выключения ПК

Батник таймер для выключения ПК. @echo off

chcp 1251 >nul

title Таймер выключения ПК

color 0A

:menu

cls

echo ================================

echo ТАЙМЕР ВЫКЛЮЧЕНИЯ КОМПЬЮТЕРА

echo ================================

echo.

echo Выберите время до выключения:

echo.

echo 1 - 30 минут

echo 2 - 1 час

echo 3 - 2 часа

echo 4 - 3 часа

echo 5 - 4 часа

echo 6 - 5 часов

echo 7 - Свое время

echo 8 - ОТМЕНИТЬ выключение

echo 0 - Выход

echo.

set /p choice="Выберите вариант [0-8]: "

if "%choice%"=="1" goto time30

if "%choice%"=="2" goto time60

if "%choice%"=="3" goto time120

if "%choice%"=="4" goto time180

if "%choice%"=="5" goto time240

if "%choice%"=="6" goto time300

if "%choice%"=="7" goto custom

if "%choice%"=="8" goto cancel

if "%choice%"=="0" goto exit

goto menu

:time30

set seconds=1800

set display_time=30 минут

goto confirm

:time60

set seconds=3600

set display_time=1 час

goto confirm

:time120

set seconds=7200

set display_time=2 часа

goto confirm

:time180

set seconds=10800

set display_time=3 часа

goto confirm

:time240

set seconds=14400

set display_time=4 часа

goto confirm

:time300

set seconds=18000

set display_time=5 часов

goto confirm

:custom

cls

echo.

set /p minutes="Введите время в минутах: "

set /a seconds=%minutes%*60

set display_time=%minutes% минут

goto confirm

:confirm

cls

echo.

echo Вы установили таймер выключения на: %display_time%

echo Компьютер будет принудительно выключен!

echo.

set /p confirm="Подтвердить? [Y/N]: "

if /i "%confirm%"=="y" goto shutdown

if /i "%confirm%"=="n" goto menu

goto confirm

:shutdown

cls

echo.

echo Таймер установлен! Выключение через %display_time%

echo Для отмены запустите этот файл и выберите вариант 8

echo.

shutdown -s -f -t %seconds% -c "Автоматическое выключение по таймеру. Для отмены: shutdown -a"

echo.

pause

goto exit

:cancel

cls

shutdown -a

echo.

echo Выключение отменено!

echo.

pause

goto menu

:exit

exit