Настройка роутера MikroTik RouterOS 7.15.3 для автоматической отправки резервных копий конфигураций на e-mail. Эта обеспечит сохранность настроек и минимизирует риск потери данных в случае непредвиденных сбоев.
Первый шаг в настройке автоматической отправки бэкапов на email — это настройка SMTP-сервера на роутере MikroTik.
Перейдем в меню Tools - Email и зададим параметры SMTP-сервера. Например:
- Server — адрес SMTP-сервера. В данном случае используется сервер yandex: smtp.yandex.ru.
- port — это порт для соединения с сервером (587 для TLS или 465 для SSL).
- start-tls — определяет, нужно ли использовать шифрование TLS для защиты соединения.
- from — это email, с которого будут отправляться письма.
user и password — это учетные данные для входа на SMTP-сервер, использовал пароли приложений.
Через терминал, отправим тестовое сообщение самому себе командой:
/tool e-mail send to=example@yandex.ru from=example@yandex.ru body=test
Для автоматизации процесса используем скрипт, который будет генерировать резервную копию и отправлять её на указанный e-mail.
Перейдем в меню System - Scripts и создадим новый скрипт:
{
:log info "starting backup process...";
:local sysver [/system package get routeros version];
:local sysname [/system identity get name];
:local rbmodel [/system router get model];
:local rbuptime [/system resource get uptime];
:log info "flushing DNS cache...";
/ip dns cache flush;
:delay 2;
:log info "deleting latest backups...";
:foreach i in=[/file find] do={:if ([:typeof [:find [/file get $i name] "$sysname-"]]!="nil") do={/file remove $i}};
:delay 2;
:log info "creating backup file...";
:local backupfile ("$sysname-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . "-v$sysver" . ".backup");
/system backup save name=$backupfile;
:delay 2;
:log info "creating script file...";
:local exportfile ("$sysname-" . [:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6] . "-v$sysver" . ".rsc");
/export show-sensitive file=$exportfile;
:delay 2;
:local files ($backupfile,$exportfile);
:log info "sending files via email...";
/tool e-mail send to=example@yandex.ru file=$files subject=("Резервная копия $rbmodel") body=("$sysname файлы резервных копий находятся во вложении.\nВремя/дата: " . [/system clock get time] . " " . [/system clock get date] . "\n\nМодель: $rbmodel\nВерсия RouterOS: $sysver\nВремя работы: $rbuptime");
:delay 4;
:log info "...system backup completed";
}
Здесь меняем адрес электронной почты на свой: /tool e-mail send to=example@yandex.ru
Теперь необходимо настроить планировщик задач, который будет запускать скрипт через определенные промежутки времени, например, раз в неделю.
Перейдите в меню System - Scheduler и добавьте новую задачу:
/system script run backup_email
В процессе работы создадутся в корне 2 файла и отправляются на e-mail. Проверяем почту.
Следуя приведенным инструкциям, вы сможете автоматизировать создание резервных копий роутера Mikrotik и обеспечить дополнительный уровень защиты ваших сетевых решений.