Как создать таблицу значений
ТЗ = Новый ТаблицаЗначений;
Как добавить колонки в таблицу значений
ТЗ.Колонки.Добавить("Артикул");
ТЗ.Колонки.Добавить("Наименование");
ТЗ.Колонки.Добавить("Количество");
ТЗ.Колонки.Добавить("ЦенаЗакупки");
ТЗ.Колонки.Добавить("ЦенаПродажи");
ТЗ.Колонки.Добавить("Группа");
Как добавить элементы (строки) в таблицу значений
НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Артикул = "123456";
НоваяСтрока.Наименование = "Трактор";
НоваяСтрока.Количество = 5;
НоваяСтрока.ЦенаЗакупки = 42588.50;
НоваяСтрока.ЦенаПродажи = 85215.00;
НоваяСтрока.Группа = "Трактора";
НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Артикул = "12345А";
НоваяСтрока.Наименование = "Трактор_12";
НоваяСтрока.Количество = 10;
НоваяСтрока.ЦенаЗакупки = 52588.50;
НоваяСтрока.Группа = "Трактора";
НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Артикул = "62345А";
НоваяСтрока.Наименование = "Сеялка_12";
НоваяСтрока.Количество = 9;
НоваяСтрока.ЦенаЗакупки = 13588.50;
НоваяСтрока.Группа = "Сеялки";
Как получить количество элементов в таблице значений
КоличествоСтрок = ТЗ.Количество();
Как найти один элемент в таблице значений
Трактор = ТЗ.Найти("Трактор_12", "Наименование");
Если Трактор = Неопределено Тогда
Сообщить("Номенклатура не найдена в таблице");
КонецЕсли;
Как найти все элементы таблицы значений, удовлетворяющие условию поиска
Трактора = ТЗ.НайтиСтроки(Новый Структура("Группа","Трактора"));
Если Трактора.Количество() = 0 Тогда
Сообщить("Не найдено ни одной строки группы Трактора");
КонецЕсли;
Для каждого СтрокаТЗ Из Трактора Цикл
Сообщить("" + СтрокаТЗ.Артикул);
КонецЦикла;
Как создать копию таблицы значений (с данными)
ТаблицаТракторов = ТЗ.Скопировать(Трактора);//это если с выборкой, в нашем случае только трактора
ТЗКопия = ТЗ.Скопировать(); //копируется вся таблица с данными
Как создать копию таблицы значений (без данных)
ЧастичнаяКопия = ТЗ.СкопироватьКолонки("Артикул,Наименование");
ПолнаяКопия = ТЗ.СкопироватьКолонки();
Как выполнить сортировку в таблице значений
по убыванию цены
ТЗ.Сортировать("ЦенаПродажи Убыв");
по возрастанию цены
ТЗ.Сортировать("ЦенаПродажи");
Как получить итог по колонке числового типа
КоличествоИтог = ТЗ.Итог("Количество");
Как свернуть таблицу значений
ТЗКопия.Свернуть("Группа","Количество");//после свертки таблица изменится останется только две колонки
Обход всех элементов таблицы значений
Для каждого Строка Из ТЗ Цикл
Сообщить("" + Строка.Наименование + ", "+ Строка.Количество);
КонецЦикла;
Как удалить элемент таблицы значений
НайденнаяСтрока = ТЗ.Найти("12345А","Артикул");
Если НайденнаяСтрока <> Неопределено Тогда
ТЗ.Удалить(НайденнаяСтрока);
КонецЕсли;
Как очистить таблицу значений
ТЗ.Очистить();
Шпаргалка по массиву
Шпаргалка по структуре
Шпаргалка по соответствию
Шпаргалка по списку значений
Шпаргалка по таблице значений
Шпаргалка по дереву значений